ProRealTime / ProScreener / ProRealTrend / ProBackTest

// VARIABLES
// ==========
// myPeriod is a variable, of type integer > 0 and defaulting to 14
// myUpperLevel a variabl, type integer > 0 default 70
// myLowerLevel a variable, type integer > 0 default 30

// Indicator settings
// ================
// In colours set 'up trend colour' to be the colour want the signal highlight to be
// set the 'down trend colour' to be the same colour to grey for both bull and bearish divergence
// set the output type to historgram


// Setup
// ========
// Add the stock PRT RSI to a chart, then in that window add this indicator as an overlay
// DONT FORGET to match both RSI settings (i.e if RSI = 14 in one make it 14 in the other!)

// Downside
// ==========
// PRT does not let you 're-write' history, so I cant highlight a peak until its passed on the chart...
// this has the effect of showing a signal but you having to look back to see where it happened.
// in this case one bar back..If anyone knows how to RSI[x] = .. that would be nice..

// current RSI
myRSI = RSI[myPeriod](customclose)

// variables we will store between bars
ONCE myLastHighPrice = MedianPrice
ONCE myLastLowPrice = MedianPrice
ONCE myLastRSIPeakVal = 1000
ONCE myLastRSITroughVal = 0

// set the output default values
myRSIBullCol = -1
myRSIBearCol = -1
myRSIBullDiv = 1
myRSIBearDiv = -1

// check for peak
//        *
//     *    *
//   2   1   0
IF (myRSI < myRSI[1]) AND (myRSI[2] < myRSI[1])  THEN
IF myRSI[1] >= myUpperLevel THEN

// great we have a peak above our level lets see if its lower than the prior peak
IF myRSI[1] < myLastRSIPeakVal THEN

//ok were lower than the last peak lets check if price was moving up
IF High[1] > myLastHighPrice THEN

// we have a bearish divergence change the bar colour
myRSIBearCol = 1

ENDIF
ENDIF

// we need to remember this peak
myLastRSIPeakVal = myRSI[1]
// update the last high price
myLasthighPrice = high[1]

ENDIF
ENDIF


// check for trough
//  2    1    0
//     *    *
//        *
IF (myRSI > myRSI[1]) AND (myRSI[2] > myRSI[1])  THEN
IF myRSI[1] <= myLowerLevel THEN
// great we have a peak above our level lets see if its lower than the prior peak
IF myRSI[1] > myLastRSITroughVal THEN

//ok were lower than the last peak lets check if price was moving up
IF Low[1] < myLastLowPrice THEN

// we have a bearish divergence change the bar colour
myRSIBullCol = 1

ENDIF

// we need to remember this trough
myLastRSITroughVal = myRSI[1]
// update the last low
myLastLowPrice = Low[1]

ENDIF
ENDIF
ENDIF

// finally output the signals
RETURN  myRSIBearDiv COLOURED BY myRSIBearCol AS "Bearish Divergence Signal", myRSIBullDiv COLOURED BY myRSIBullCol  AS "Bullish Divergence Signal"

REM Important to note is that the previous bar variable is 'remembered'
REM so when you come to average you get the correct previous bar value

ONCE haClose = 0
ONCE haOpen = 0
ONCE haHigh = 0
ONCE haLow = 0

IF BarIndex = 0 THEN
haClose = TotalPrice
haOpen = Open
ELSE
haOpen = (haClose + haOpen)/2
haClose = TotalPrice
ENDIF

haHigh = Max(High, haOpen)
haLow = Min(Low,haOpen)

return haclose as "H-A Close", haopen as "H-A Open", hahigh as "H-A High", halow as "H-A Low"

// VARIABLES
// ==========
// myPeriod is a variable, of type integer > 0 and defaulting to 14
// myUpperLevel a variabl, type integer > 0 default 70
// myLowerLevel a variable, type integer > 0 default 30
// useHA, a boolean, type boolean, default = 'False' give you an option to use high/low of HAHigh / HALow

// Indicator settings
// ================
// In colours set 'up trend colour' to be the colour want the signal highlight to be
// set the 'down trend colour' to be the same colour to grey for both bull and bearish divergence
// set the output type to historgram


// Setup
// ========
// Add the stock PRT RSI to a chart, then in that window add this indicator as an overlay
// DONT FORGET to match both RSI settings (i.e if RSI = 14 in one make it 14 in the other!)

// Downside
// ==========
// PRT does not let you 're-write' history, so I cant highlight a peak until its passed on the chart...
// this has the effect of showing a signal but you having to look back to see where it happened.
// in this case one bar back..If anyone knows how to RSI[x] = .. that would be nice..

// current RSI
myRSI = RSI[myPeriod](customclose)

// variables we will store between bars
ONCE myLastHighPrice = 0
ONCE myLastLowPrice = 1000
ONCE myLastRSIPeakVal = 1000
ONCE myLastRSITroughVal = 0

// set the output default values
myRSIBullCol = -1
myRSIBearCol = -1
myRSIBullDiv = 1
myRSIBearDiv = -1

IF myUseHA THEN
ignored , ignored, myHAHigh, myHALow = CALL "Heikin Ashi"
myHigh = myHAHigh[1]
myLow = myHALow[1]
ELSE
myHigh = high[1] // myHighx
myLow = low[1] // myLowx
ENDIF


// check for peak
//        *
//     *    *
//   2   1   0
IF (myRSI < myRSI[1]) AND (myRSI[2] < myRSI[1])  THEN
IF myRSI[1] >= myUpperLevel THEN

// great we have a peak above our level lets see if its lower than the prior peak
IF myRSI[1] < myLastRSIPeakVal THEN

//ok were lower than the last peak lets check if price was moving up
IF myHigh > myLastHighPrice THEN

// we have a bearish divergence change the bar colour
myRSIBearCol = 1

ENDIF
ENDIF

// we need to remember this peak
myLastRSIPeakVal = myRSI[1]
// update the last high price
myLasthighPrice = myHigh

ENDIF
ENDIF


// check for trough
//  2    1    0
//     *    *
//        *
IF (myRSI > myRSI[1]) AND (myRSI[2] > myRSI[1])  THEN
IF myRSI[1] <= myLowerLevel THEN

// great we have a peak below  our level lets see if its higher than the prior peak
IF myRSI[1] > myLastRSITroughVal THEN

//ok were lower than the last peak lets check if price was moving up
IF myLow < myLastLowPrice THEN

// we have a bearish divergence change the bar colour
myRSIBullCol = 1

ENDIF
ENDIF

// we need to remember this trough
myLastRSITroughVal = myRSI[1]
// update the last low
myLastLowPrice = myLow

ENDIF
ENDIF

// finally output the signals
RETURN  myRSIBearDiv COLOURED BY myRSIBearCol AS "Bearish Divergence Signal", myRSIBullDiv COLOURED BY myRSIBullCol  AS "Bullish Divergence Signal"